http://www.youtube.com/watch?v=HUEvRyemKSg

the video is licensed under CC-BY and so is the audio stream. so – for those of you who want just the audio stream for a long trip and their mp3 player, i did extract the audio from the high quality video and put up a torrent here: http://tors.in/corydoctorow28c3 – here is the magnet link. i will seed
and for everyone who is more into http here is the file for direct download. seed with that if you like.

No related posts.

http://www.youtube.com/watch?v=j9NV7lZxK08

recently i finished my latest project: a RFID Door Opener.

besides the fun while hacking it, it improves the security of the door. since it’s not an outside door but the door to the garage, it’s construction does not allow to mount a more secure lock. so locking it from the outside when leaving is a bit bothersome.
the new auto-lock feature, which allows the door to auto-lock itself, saves some time and works around the lazy user, who wouldn’t have locked it.
additionally it is now easy to add or remove the right of access by adding or deleting the RFID’s unique number from the system. revoking someone’s right of access is far more difficult with a normal key.

beside an arduino i’m using an easydriver to drive the stepper and a RFID reader from seeedstudio.

below you can see the schematics of the setup. the ends marked with Ard X go to a port of the arduino, which is the brain of the lock:

Schematics for the build

/**
 * door lock application (c) 2011 Florian Klien
 * some code parts are borrowed from different authors   thx
 */

#include <NewSoftSerial.h>

#define rxPin 2
#define txPin 3

// door defs

#define DOOR_SENS  3 // analog
#define DRIVER_SWITCH 6
#define DOOR_SW 2 // analog

// motor defs
#define DIR_PIN 7
#define STEP_PIN 8
#define ledIN 5
#define ledOUT 11

NewSoftSerial rfid = NewSoftSerial( rxPin, txPin );

// The tag database consists of two parts. The first part is an array of
// tag values with each tag taking up 5 bytes. The second is a list of
// names with one name for each tag (ie: group of 5 bytes).
char* allowedTags[] = {
  "AABBCCDDEE",         // Tag 1
  "AABBCCDDEE",         // Tag 2
};

// List of names to associate with the matching tag IDs
char* tagName[] = {
  "User1",         // Tag 1
  "User2",         // Tag 2
};

// software version number:
char* software_version = "1.1";

// Check the number of tags defined
int numberOfTags = sizeof(allowedTags)/sizeof(allowedTags[0]);

int incomingByte = 0;    // To store incoming serial data

boolean locked = true;
int door_open = 0; // pseudo digital
boolean prev_status = false;
boolean auto_lock = true;
//unsigned long auto_lock_time = 0;
int auto_lock_delay = 5; // in seconds
int auto_lock_switch_time = 2; // in seconds
int status_led = 0;
unsigned long status_led_time = millis();
boolean status_led_on = false;

unsigned long status_breathe_time = millis();
int breathe_delay = 10;
boolean breathe_up = true;
int breathe_i = 15;

unsigned long last_successful_rfid_read = 0;
int rfid_success_timeout = 5000; // millis

float lock_speed = 1;

/**
 * Setup
 */
unsigned long time_door = millis();
unsigned long time_switch = millis();
long debounce = 500;

void setup() {
  pinMode(ledIN, OUTPUT);
  pinMode(ledOUT, OUTPUT);
  digitalWrite(ledIN, HIGH);
  digitalWrite(ledOUT, HIGH);
  delay(300);
  digitalWrite(ledIN, LOW);
  digitalWrite(ledOUT, LOW);

  pinMode(DRIVER_SWITCH, OUTPUT);
  digitalWrite(DRIVER_SWITCH, LOW);
  pinMode(DIR_PIN, OUTPUT);
  digitalWrite(DIR_PIN, LOW);
  pinMode(STEP_PIN, OUTPUT);
  digitalWrite(STEP_PIN, LOW);
  pinMode(DOOR_SENS,INPUT);
  pinMode(DOOR_SW,INPUT);

  Serial.begin(9600);   // Serial port for connection to host
  rfid.begin(9600);      // Serial port for connection to RFID module

  Serial.println("RFID reader starting up");
  delay(1000);
  Serial.println("done");
  Serial.print("Software Version no: ");
  Serial.println(software_version);
  Serial.print("door locked: ");
  Serial.print(locked, DEC);
  Serial.print("\n");
  Serial.print("door closed: ");
  Serial.print(!door_open, DEC);
  Serial.print("\n");
}

/**
 * Loop
 * non-blocking version of each function!
 */
void loop() {
  readRFID();
  doorSensor();
  doorSwitch();
  statusLed();
}

void doorSensor(){
  // pseudo digital
  door_open = analogRead(DOOR_SENS);
  if(millis() - time_door > debounce){
    if (door_open <= 500 && prev_status == false){
      Serial.println("Door: opened");
      prev_status = true;
      locked = false;
    }else  if(door_open > 500 && prev_status == true){
      Serial.println("Door: closed");
      prev_status = false;
      if(auto_lock){
        Serial.println("locking door automatically...");
        delay(auto_lock_delay*1000);
        lock();
        locked = true;
      }
    }
    time_door = millis();
  }
}

void doorSwitch(){
  int dstimer = 0;
  int door_switch = analogRead(DOOR_SW); // pseudo digital
  if(millis() - time_switch > debounce && door_switch >= 300){
    while (analogRead(DOOR_SW) >= 300) {
      delay(100);
      dstimer++;
    }
    Serial.println(door_switch,DEC);
    Serial.println(dstimer,DEC);
    if (dstimer < auto_lock_switch_time*10) { //button has been pressed less than 2 seconds = 1000/100
        if (locked == false){
          Serial.println("door locked");
          locked = true;
          lock();
        }else if(locked == true){
          Serial.println("door unlocked");
          locked = false;
          unlock();
      }
    }else {
      // auto_unlock off/on
      if(auto_lock == true){
        Serial.println("auto_lock off");
        auto_lock = false;
      }else{
        Serial.println("auto_lock on");
        auto_lock = true;
      }
      analogWrite(ledIN, 0); // resetting output

    }
    time_switch = millis();
  }
}

// breathing status led on the inside
void statusBreathe(){
  if( (status_breathe_time + breathe_delay) < millis() ){
    analogWrite(ledIN, breathe_i/1.5);
    status_breathe_time = millis();
    if (breathe_up == true){
      if (breathe_i > 150) {
        breathe_delay = 4;
      }
      if ((breathe_i > 125) && (breathe_i < 151)) {
        breathe_delay = 5;
      }
      if (( breathe_i > 100) && (breathe_i < 126)) {
        breathe_delay = 7;
      }
      if (( breathe_i > 75) && (breathe_i < 101)) {
        breathe_delay = 10;
      }
      if (( breathe_i > 50) && (breathe_i < 76)) {
        breathe_delay = 14;
      }
      if (( breathe_i > 25) && (breathe_i < 51)) {
        breathe_delay = 18;
      }
      if (( breathe_i > 1) && (breathe_i < 26)) {
        breathe_delay = 19;
      }
      breathe_i += 1;
      if( breathe_i >= 255 ){
        breathe_up = false;
      }
    }else{
      if (breathe_i > 150) {
        breathe_delay = 4;
      }
      if ((breathe_i > 125) && (breathe_i < 151)) {
        breathe_delay = 5;
      }
      if (( breathe_i > 100) && (breathe_i < 126)) {
        breathe_delay = 7;
      }
      if (( breathe_i > 75) && (breathe_i < 101)) {
        breathe_delay = 10;
      }
      if (( breathe_i > 50) && (breathe_i < 76)) {
        breathe_delay = 14;
      }
      if (( breathe_i > 25) && (breathe_i < 51)) {
        breathe_delay = 18;
      }
      if (( breathe_i > 1) && (breathe_i < 26)) {
        breathe_delay = 19;
      }
      breathe_i -= 1;
      if( breathe_i <= 15 ){
        breathe_up = true;
        breathe_delay = 970/2;
      }
    }
  }
}

void statusLed(){
  if(auto_lock == false){
    status_led = 150;
  }else{
    // set this to > 0 if you want the status led to blink in default mode
    status_led = 0;
    if(status_led == 0){
      statusBreathe();
    }
  }
  if(millis() - status_led_time >= status_led && status_led != 0){
    status_led_on = !status_led_on;
    digitalWrite(ledIN,status_led_on);
    status_led_time = millis();
  }
}

void readRFID(){
  byte i         = 0;
  byte val       = 0;
  byte checksum  = 0;
  byte bytesRead = 0;
  byte tempByte  = 0;
  byte tagBytes[6];    // "Unique" tags are only 5 bytes but we need an extra byte for the checksum
  char tagValue[10];

  if(rfid.available()>0){
    if((val = rfid.read()) == 2) {        // Check for header
    bytesRead = 0;
    while (bytesRead < 12) {            // Read 10 digit code + 2 digit checksum
      val = rfid.read();
      Serial.print(val,BYTE);
      // Append the first 10 bytes (0 to 9) to the raw tag value
      if (bytesRead < 10)
      {
        tagValue[bytesRead] = val;
      }

      // Check if this is a header or stop byte before the 10 digit reading is complete
      if((val == 0x0D)||(val == 0x0A)||(val == 0x03)||(val == 0x02)) {
        break;                          // Stop reading
      }

      // Ascii/Hex conversion:
      if ((val >= '0') && (val <= '9')) {
        val = val - '0';
      }
      else if ((val >= 'A') && (val <= 'F')) {
        val = 10 + val - 'A';
      }

      // Every two hex-digits, add a byte to the code:
      if (bytesRead & 1 == 1) {
        // Make space for this hex-digit by shifting the previous digit 4 bits to the left
        tagBytes[bytesRead >> 1] = (val | (tempByte << 4));

        if (bytesRead >> 1 == 5) {                // If we're at the checksum byte,
          checksum ^= tagBytes[bytesRead >> 1];   // Calculate the checksum... (XOR)
        };
      } else {
        tempByte = val;                           // Store the first hex digit first
      };

      bytesRead++;                                // Ready to read next digit
    }

    // Send the result to the host connected via USB
    if (bytesRead == 12) {                        // 12 digit read is complete
      tagValue[10] = '\0';                        // Null-terminate the string

      Serial.print("Tag read: ");
      for (i=0; i<5; i++) {
        // Add a leading 0 to pad out values below 16
        if (tagBytes[i] < 16) {
          Serial.print("0");
        }
        Serial.print(tagBytes[i], HEX);
      }
      Serial.println();

      Serial.print("Checksum: ");
      Serial.print(tagBytes[5], HEX);
      Serial.println(tagBytes[5] == checksum ? " -- passed." : " -- error.");

      // Show the raw tag value
      //Serial.print("VALUE: ");
      //Serial.println(tagValue);
      Serial.print("door_open: ");
      Serial.println(door_open,DEC);
      // Search the tag database for this particular tag
      int tagId = findTag( tagValue );

      // Only fire the strike plate if this tag was found in the database
      if( tagId > 0 )
      {
        Serial.print("Authorized tag ID ");
        Serial.print(tagId);
        if(door_open > 500 && (last_successful_rfid_read + rfid_success_timeout) < millis() ){
          Serial.print(": unlocking for ");
          Serial.println(tagName[tagId - 1]);   // Get the name for this tag from the database
          unlock();
          last_successful_rfid_read = millis();
          delay(2000);
        }
      } else {
        Serial.println("Tag not authorized");
        //failSound();
        for (int i=0;i<7;i++){ // FIXXME nonblocking version?
          digitalWrite(ledOUT, HIGH);
          digitalWrite(ledIN, HIGH);
          delay(100);
          digitalWrite(ledOUT, LOW);
          digitalWrite(ledIN, LOW);
          delay(80);
        }
      }
      Serial.println();     // Blank separator line in output
    }

    bytesRead = 0;
  }
  }
}

/**
 * Fire the relay to activate the strike plate for the configured
 * number of seconds.
 */
void unlock() {
  digitalWrite(ledOUT, HIGH);
  digitalWrite(ledIN, HIGH);
  delay(100);
  // if your stepper is powerful enough you can use full speed
  rotateDeg(-800, 0.6);
  digitalWrite(ledIN, LOW);
  digitalWrite(ledOUT, LOW);
  locked = false;
}

void lock(){
  digitalWrite(ledOUT, HIGH);
  digitalWrite(ledIN, HIGH);
  delay(100);
  rotateDeg(800, 1);
  digitalWrite(ledIN, LOW);
  digitalWrite(ledOUT, LOW);
  locked = true;
}

void rotate(int steps, float speed){

  // power driver
  digitalWrite(DRIVER_SWITCH,HIGH);
  delay(200);
  //rotate a specific number of microsteps (8 microsteps per step) - (negitive for reverse movement)
  //speed is any number from .01 -> 1 with 1 being fastest - Slower is stronger
  int dir = (steps > 0)? HIGH:LOW;
  steps = abs(steps);

  digitalWrite(DIR_PIN,dir); 

  float usDelay = (1/speed) * 250;

  for(int i=0; i < steps; i++){
    digitalWrite(STEP_PIN, HIGH);
    delayMicroseconds(usDelay); 

    digitalWrite(STEP_PIN, LOW);
    delayMicroseconds(usDelay);
  }

  // unpower driver
  delay(200);
  digitalWrite(DRIVER_SWITCH,LOW);
} 

void rotateDeg(float deg, float speed){
  // power driver
  digitalWrite(DRIVER_SWITCH,HIGH);
  delay(200);
  //rotate a specific number of degrees (negative for reverse movement)
  //speed is any number from .01 -> 1 with 1 being fastest - Slower is stronger
  int dir = (deg > 0)? HIGH:LOW;
  digitalWrite(DIR_PIN,dir); 

  int steps = abs(deg)*(1/0.225);
  float usDelay = (1/speed) * 250;

  for(int i=0; i < steps; i++){
    digitalWrite(STEP_PIN, HIGH);
    delayMicroseconds(usDelay); 

    digitalWrite(STEP_PIN, LOW);
    delayMicroseconds(usDelay);
  }
  // unpower driver
  delay(200);
  digitalWrite(DRIVER_SWITCH,LOW);
}

/**
 * Search for a specific tag in the database
 */
int findTag( char tagValue[10] ) {
  for (int thisCard = 0; thisCard < numberOfTags; thisCard++) {
    // Check if the tag value matches this row in the tag database
    if(strcmp(tagValue, allowedTags[thisCard]) == 0)
    {
      // The row in the database starts at 0, so add 1 to the result so
      // that the card ID starts from 1 instead (0 represents "no match")
      return(thisCard + 1);
    }
  }
  // If we don't find the tag return a tag ID of 0 to show there was no match
  return(0);
}

Related posts:

1. Non-blocking breathing led for arduino…
2. pin garage door opener…
3. DIY time-lapse timer…

the result looks like this:

http://www.youtube.com/watch?v=TjzFo63svmM

here is my non-blocking code for a breathing led with arduino:

/*
"Breathing non-blocking sleep LED."
Florian Klien 2011
blog.flo.cx
based on work from Jeremy Saglimbeni (thecustomgeek.com)
*/
#define LED 5 // any PWM led will do
unsigned long status_breathe_time = millis();
int breathe_delay = 10;
boolean breathe_up = true;
int breathe_i = 15;

void setup() { // bring the LED up nicely from being off
  for(i = 0 ; i <= 15; i+=1)
  {
    analogWrite(11, i);
    delay(5);
  }
}

void loop()
{
  nonBlockingBreathe();
  otherImportantNonBlockingStuff();
}

void nonBlockingBreathe(){
  if( (status_breathe_time + breathe_delay) < millis() ){
    analogWrite(LED, breathe_i);
    status_breathe_time = millis();
    if (breathe_up == true){
      if (breathe_i > 150) {
        breathe_delay = 4;
      }
      if ((breathe_i > 125) && (breathe_i < 151)) {
        breathe_delay = 5;
      }
      if (( breathe_i > 100) && (breathe_i < 126)) {
        breathe_delay = 7;
      }
      if (( breathe_i > 75) && (breathe_i < 101)) {
        breathe_delay = 10;
      }
      if (( breathe_i > 50) && (breathe_i < 76)) {
        breathe_delay = 14;
      }
      if (( breathe_i > 25) && (breathe_i < 51)) {
        breathe_delay = 18;
      }
      if (( breathe_i > 1) && (breathe_i < 26)) {
        breathe_delay = 19;
      }
      breathe_i += 1;
      if( breathe_i >= 255 ){
        breathe_up = false;
      }
    }else{
      if (breathe_i > 150) {
        breathe_delay = 4;
      }
      if ((breathe_i > 125) && (breathe_i < 151)) {
        breathe_delay = 5;
      }
      if (( breathe_i > 100) && (breathe_i < 126)) {
        breathe_delay = 7;
      }
      if (( breathe_i > 75) && (breathe_i < 101)) {
        breathe_delay = 10;
      }
      if (( breathe_i > 50) && (breathe_i < 76)) {
        breathe_delay = 14;
      }
      if (( breathe_i > 25) && (breathe_i < 51)) {
        breathe_delay = 18;
      }
      if (( breathe_i > 1) && (breathe_i < 26)) {
        breathe_delay = 19;
      }
      breathe_i -= 1;
      if( breathe_i <= 15 ){
        breathe_up = true;
        breathe_delay = 970;
      }
    }
  }
}

original code came from thecustomgeek.com

Related posts:

1. RFID Door Opener…
2. DIY time-lapse timer…

wie es aussieht zeichnet apple mit dem iOS4 die positionsdaten des besitzers (oder des telefons) auf und speichert diese in einer datenbank am rechner ab. diese daten sind nicht gerade spärlich.
es lassen sich deutliche bewegungsprofile erstellen und sehr schön darstellen (siehe bild).

iPhone Tracking Data on a Map (quelle)

golem und engadget haben hierzu schöne videos in ihren bericht eingebunden.

wieso speichert apple diese daten? werden diese beim ‘anonymen’ feedback mitgeschickt?

derzeit schaut es nicht so aus als wären diese daten irgendwem zugänglich. dennoch. wenn diese daten gespeichert werden, können sie gestohlen, misbraucht und verwertet werden; und das nicht immer vom rechtmässigen eigentümer. wer immer diese daten in die hände bekommt kann alles damit tun. ich bin hier zwigespalten zwischen datenschutz und datamining. die daten aller iphone nutzer wären ein wundervoller datensatz. das muss man apple lassen: sie wissen wie man an tolle daten kommt

der artikel vom o’reilly radar ist lesenswert.

wer ein iphone sein eigen nennt kann auch die software ausprobieren und nachsehen wo es sich die letzte zeit aufgehalten hat.

UPDATE 110422 1910: android nutzer kamen sich schon fast benachteiligt vor; aber es stellt sich heraus google macht mit android genau das gleiche!

Android Location Data (erstellt mit android-locdump viewer {source})

aus obigem bild sieht man, dass ich in graz das linke murufer (rechts im bild) vorziehe.

bei android geräten liegen die daten im folder “/data/data/com.google.android.location/files” und heissen “cache.cell” und “cache.wifi”. sie lassen sich mit einem kleinen python script von @packetlss extrahieren und verwerten.
google schickt sich wlan daten (sprich BSSIDs von accesspoints mit entsprechender peilung) selbst zu und verwertet sie in einer datenbank die dann herangezogen wird um andere geräte genauer zu positionieren. ein kleines webtool von @samykamkar greift auf googles datenbank zu und hilft dabei mac adressen bestimmten koordinaten zuzuordnen. gebt dort mal die mac adresse eures eigenen wlan hotspots ein!

UPDATE 110426 1220: ich habe die letzten tage die option ‘standort&sicherheit -> drahtlosnetzwerke’ abgestellt gehabt und tatsächlich. das android gerät loggt nichts mehr mit. am iphone soll das ja nicht der fall sein – stellt man dort das loggen ab, passiert es trotzdem…

No related posts.

lustigerweise scheint Belgrad einen sehr hohen bedarf zu haben. dabei schlägt Belgrad sogar New York City.

Deaddrops in New York City und Belgrad (Beograd)

UPDATE 110503 1200: ich hab die deaddrops in graz nochmal gezählt.
es sind jetzt 6:
schwimmschulkai, grazbachgasse, lichtenfelsgasse, schillerstrasse, alte poststrasse, inffeldgasse

Related posts:

1. Dead Drops…

der erste Grazer Dead Drop

auf die heutige zeit umgelegt sind das offline datenträger (usb-sticks) die an ‘geheimen’ öffentlichen orten hinterlegt – sprich: eingemauert oder angeklebt werden und so jedem zugänglich sind. jeder darf auf dem datenträger etwas ablegen und jeder darf daten herunterladen.

seit heute hat graz auch einen dead drop. hoffentlich kommen noch einige dazu. gesamt sind jetzt weltweit etwa 397 GB speicherplatz frei zugänglich.

ich bin wirklich gespannt ob und wenn in welche richtung diese bewegung die ganze copyright und file sharing diskussion führt.

update:
es hat keine 3 tage gedauert und schon gibt es einen zweiten dead drop in graz. weiter so.

update 11 04 06:
es kamen noch 2 dead drops hinzu: lichtenfelsgasse, schillerstrasse

Related posts:

1. 1 TB deaddrop speicher…

video takes a lot of space. since time-lapse videos are much more interesting if you cover a big time interval you either have to have a huge memory card or you manage to turn down the amount of data that comes in. i decided to do the latter. since canon cams don’t come with a time-lapse function built in, one has to find an external time that does the job. there are several cheap external cable timers available. they just have one problem. they just do time intervals from 1 to about 9999 seconds. i needed less. 300 ms (0,3 sec) should be my smallest interval. so i built my own.

the second try - opened box

the second iteration is built on an arduino diecimila. on top i use a prototyping board which holds a 16×2 display. as input there is a potentiometer that chooses the timing interval. the display shows exactly what interval is chosen.

final 2nd iteration

to reduce the risk of toasting my camera i separated the arduino circuit with an opto-isolator to the cable.

the next step is to reduce the size of the box by finding a smaller form factor and using the arduino pro mini.

here is the arduino code:

/*
  Time-lapse timer

Copyright 2011 Florian Klien. All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are
permitted provided that the following conditions are met:

   1. Redistributions of source code must retain the above copyright notice, this list of
      conditions and the following disclaimer.

   2. Redistributions in binary form must reproduce the above copyright notice, this list
      of conditions and the following disclaimer in the documentation and/or other materials
      provided with the distribution.

THIS SOFTWARE IS PROVIDED BY Florian Klien ``AS IS AND ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL Florian Klien OR
CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

#include <LiquidCrystal.h>

#define LCDRS 11
#define LCDENABLE 10
#define LCDD4 7
#define LCDD5 6
#define LCDD6 5
#define LCDD7 4
#define POTPIN 2 // potentiometer pin
#define LEDPIN 12 // pin for an optional led
#define SWITCHPIN 8
// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(LCDRS, LCDENABLE, LCDD4, LCDD5, LCDD6, LCDD7);

double val = 0;
int ts = 0;
unsigned long int steps[] = {333,500,750,
               1000,1500,2000,
               2500,3000,4000,
               5000,6000,7000,
               8000,9000,10000,
               12000,15000,20000,
               25000,30000,35000,
               40000,45000,50000,
               55000,60000,90000,
               120000,240000,300000,
               360000,420000,480000,
               540000,600000,900000,
               1200000
             }; // in ms

unsigned long lasttime = 0;

void setup() {
  // set up the LCD's number of columns and rows:
  lcd.begin(16, 2);
  // Print a message to the LCD.
  lcd.print("timer set to:");
  Serial.begin(9600);
  //lasttime = millis();
  pinMode(LEDPIN, OUTPUT);
  pinMode(SWITCHPIN, OUTPUT);
  digitalWrite(LEDPIN,HIGH);
  delay(500);
  digitalWrite(LEDPIN,LOW);
}

void loop() {
  val = analogRead(POTPIN);
  ts = map(val, 0, 1023, 0, 37);
  lcd.setCursor(0, 1);
  double time = (float)steps[ts]/1000;
  lcd.print(time);
  lcd.print(" sec ");
  lcd.print((float)(millis()-lasttime)/1000);
  lcd.print("    ");
  if((millis()-lasttime) > steps[ts]){
    digitalWrite(LEDPIN, HIGH);
    digitalWrite(SWITCHPIN,HIGH);
    delay(100);
    digitalWrite(LEDPIN, LOW);
    digitalWrite(SWITCHPIN,LOW);
    lasttime = millis();
  }
}

update:
here is a little testvideo:

Related posts:

1. miniature time-lapse with fake tilt shift (howto)…
2. RFID Door Opener…

HD+-Logo

HD+ ist so ein beispiel. um nichts besser aber der kunde darf dann keine werbung mehr überspringen, keinen timeshift machen und natürlich keine aufnahmen mehr auf eine andere festplatte verlagern. kosten tut es auch noch was: zusätzliche gebühren und natürlich neue receiver sind fällig.

da fällt mir nur immer diese grafik ein:

zu allem überfluss muss sich jetzt der konsument wirklich vor jeder zusatzbezeichnung mit dem PLUS (+) fürchten. denn das könnte ja seine rechte und gewohnheiten deutlich einschränken.
nur bei itunes war ja das plus die bezeichnung für die DRM-freie version der musik…

No related posts.